Building a Simple Soil Moisture Sensor

This article is a sub-article of another article (Growing Purple Strawberries).  In this article I build a simple soil moisture indicator.

Simple Moisture Monitor

The plan is to have a device that has a red LED when the soil of a plant is dry, and a green LED when there is adequate soil moisture.  This is a very simple circuit so I don’t need to make any sketches and can jump straight to a prototype:

As you can see, when I apply the moist tissue to the sensor the LED switches from red to green.  I used the following parts:

  • Arduino
  • RGB LED Light
  • YL-69 Moisture Sensor
  • YL-38 Signal Sensor/Decoder
  • 220Ω Resistor

And here is the Arduino source code:

void setup()
{
   pinMode(3, INPUT_PULLUP);
   pinMode(4, OUTPUT);
   pinMode(5, OUTPUT);
}

void loop()
{
   digitalWrite(4, !digitalRead(3));
   digitalWrite(5, digitalRead(3));
}

The YL-38 has an extremely useful calibration dial that can be used to set the level of moisture at which the digital bit is triggered.

Switching Over to a ATtiny85

At first I was going to build a permanent prototype using a Digispark, but the ATtiny85 had a lot of advantages over the Digispark and it will make a great microprocessor for this project.  I also bought a USBasp programmer for it that I haven’t yet used.  Benefits of to the ATtiny85 compared to the Digispark is that it is smaller, has a guaranteed 20KΩ input pull-up resistor on all pins, it’s cheaper, it doesn’t have an on-board LED that drains power, it is easy to set the clock speed to 1MHz to save power and it is very reliable.  The downside is that it can’t just be plugged in to the USB port for programming (but this also means I can build a fancy programming unit); it also doesn’t have an on-board testing LED light (not a big deal), finally, it doesn’t have an on-board 5V power regulator (this is a big one, I will need to figure out something for powering the ATTiny85).

I put together a USBasp programmer (and made a post on doing it too).

I can quickly program ATtiny chips by putting the chip in the IC socket and plugging an USBasp in the ribbon socket.
I can quickly program ATtiny chips by putting the chip in the IC socket and plugging an USBasp in the ribbon socket.

I changed the pin numbers and uploaded the program to the ATtiny in no time.  I used two AA batteries to power the project, this was more than enough power for the ATtiny85, but a little less for the soil sensor, which became very sensitive and needed an increased amount of moisture to trigger.  I will need to run some soil tests to determine if we can run this project of 3V or will need 5V.  Here it is running on an ATtiny:

And here is the new source code:

void setup()
{
  pinMode(0, INPUT_PULLUP);
  pinMode(1, OUTPUT);
  pinMode(2, OUTPUT);
}

void loop()
{ 
  digitalWrite(1, digitalRead(0));
  digitalWrite(2, !digitalRead(0));
}

The Power Struggle

I now need to find a way to power this whole thing, right now it is running off two AA batteries.  AA batteries have about 2,500 mAh of power; using a multimeter I can see the draw of this project is about 7.8 mA @ 3V.  Testing each component individually, it appears the ATtiny is comsuming about 1.1 mA, the LED about 2.5 mA and the rest by the sensor.

If we were to power this project as-is, using AA batteries it could theoretically run for 320 hours (it won’t because the voltage drops as the batteries age).  That isn’t good enough, we either need to reduce consumption significantly, or find a different power source; I believe we can reduce consumption by at least 95%.

We can get a huge savings by not running the LED and sensor continuously.  We can drop it’s duty cycle by a huge amount.  We can blink the LED for 500 ms every 10 seconds, meaning it will reduce power consumption of the sensor and the LED by 95% (We might even be able to get away with a smaller duty cycle).

After trying it out, it’s a win; realistically, the device would still work even if the duty cycle was 0.5ms per 30s.  Using a multimeter, I am seeing a current of about 1mA when the LED and sensor is off, and 7.7mA when it is on.  Meaning (based on a 30s cycle), 1.66% of the time we are using 7.7mA and 98.3% of the time, we are using 1mA.  This makes our average consumption 1.11mA; therefore, on 2x AA batteries we can run the device for 2,252 hours (or three months).

But wait, there’s more!  We can reduce power consumption even more.  At this point most of the power is being drained is by the continuous 1mA of the ATtiny85.  This draw can be reduce by putting the chip in low power mode, and putting it to sleep when the sensor and LED is off.

With a few updates to the code, I have the chip sleeping for 40s, using 0.004 mA and the system awake for 500ms consuming 5mA.  This means the average consumption of the system is just 0.33mA.  Now, if we put in two fresh AA batteries, they should last about 1 year; much more acceptable.

To save even more power I made a few final tweaks:

  1. Blink the LED instead of have it solid reduces consumption when the LED is on by 1/2 and it makes the LED more noticeable.
  2. Turn off the moisture sensor when the LED is blinking, the sensor only needs to be on for a few milliseconds to get the moisture reading.
  3. Reduce the sensor interval to 80 seconds, it is more than enough.

With all this done, I estimate my average current is 0.08mA, meaning on two batteries we will be able to run the device for about 3.5 years.

Now I just need to calibrate the sensitivity, solder it all together and we’re good to go! Here is the final code:

#include <avr/wdt.h>
#include <avr/sleep.h>

int cnt = 0;

void setup()
{
  pinMode(0, INPUT_PULLUP);  //The sensors goes low when the soil is moist, and must be pulled up otherwise
  pinMode(1, OUTPUT);        //The green LED (using a common anode RGB LED)
  pinMode(2, OUTPUT);        //The red LED (same RGB LED as the green one)

  pinMode(3, OUTPUT);        //We will use pin 3 as the negative for the sensor, so we can turn it off when not in use

    
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);  //When we go to sleep, use SLEEP_MODE_PWR_DOWN, the mode that uses the LEAST amount of power
  sleep_enable(); //Allow the ATtiny to go to sleep.

  
  cli();  //Disable interupts temporarly why we do some important work
  wdt_reset();  //Reset the watchdog counter for good measure
  WDTCR  |= (1<<WDCE) | (1<<WDE); //Set these bits in order to set the watch dog configs
  WDTCR  = (1<<WDIE) | (1<<WDP3) | (1<<WDP0); //Set the watchdog to 8s.
  sei();
}

void loop()
{ 
  if (cnt == 0) //Only 1 in 10 loops will actually check the soil, since 8s is the maximum watchdog interval and we want to run this code every 80s.  9 times out of 10, we just put the chip back to sleep.
  {
  
    digitalWrite(3, LOW);//Turn on the sensor
    delay(10);  //Give it a moment, just to be safe
  
    bool moist = digitalRead(0); //Read the sensor
    delay(10);  //Give it a moment, just to be safe.
    

    digitalWrite(3, HIGH);     //Turn off sensor

    for (int i = 0; i < 20; i++) //Blink the LED 20 times
    {
      //Set the LEDs based on the moisture reading
      digitalWrite(1, moist);
      digitalWrite(2, !moist);

      delay(50); //Wait 50ms

      //Turn off both LEDs
      digitalWrite(1, HIGH);
      digitalWrite(2, HIGH);

      delay(50);  //Wait 50ms
    }
  }

  //Sleep
  ADCSRA &= ~(1<<ADEN); //Disable the ADC while in sleep (saves .25mA)
  sleep_mode(); //Enter sleep for 8s, reducing power consumption to 0.004mA!
  sleep_disable();  //Where to pick up after coming out of sleep.
  ADCSRA |= (1<<ADEN);  //Turn the ADC back on.
}

ISR(WDT_vect) // Watchdog timer interrupt.
{
  cnt++; //Increment a counter
  if (cnt == 10) { cnt = 0; } //Reset the counter every 10 interrupts
}

A  quick note on the code: I already programmed the chip and soldered it before realizing a couple of things. I tried to reprogram the chip with testing leads, but the wiring didn’t allow it.  The two things I noticed:

First, you don’t need so much green blinking, consider only 1 or 2 blinks for when the soil is moist (if that).  All the green blinking reminds me of Homer Simpson’s everything is okay alarm.

Second, you don’t need to turn on the ADC every time the watchdog wakes up the ATtiny.  You can probably get away with only turning it on on the cycles where the soil is tested; you may not even need it then (I wasn’t able to test this, but if anyone else does, let me know how it turns out).

Hardware Layout

I never made a circuit diagram for this device since it was so simple, but I will describe the circuit below:

  1. Two AA batteries to power the system.
  2. YL-38 Decoder:
    1. Plug in the YL-69 the only way it can be plugged in.
    2. Vcc goes to + of the battery.
    3. Ground goes to pin 3 of the ATtiny.
    4. Digital output goes to pin 0 of the ATtiny.
    5. Analog output is not connected to anything.
  3. RGB LED (Common anode):
    1. Vcc goes to + of the battery with the resistor between them.
    2. Red cathode goes to pin 1 of the ATtiny.
    3. Green cathode goes to pin 2 of the ATtiny.
  4. ATtiny:
    1. Vcc goes to + of the battery
    2. Ground goes to – of the battery

Test your circuit on a breadboard before soldering.

The Final Product

Here are a couple of pictures of the whole thing soldered together on the strawberry plant.

Soil Sensor Indicating Moist Soil
Soil Sensor Indicating Moist Soil
Soil Sensor Detailed Circuit
Soil Sensor Detailed Circuit

One thought on “Building a Simple Soil Moisture Sensor”

Leave a Reply to Ritesh Khanna Cancel reply

Your email address will not be published.